UPDATE 2022-04-14: Development of this package has been discontinued: https://protesilaos.com/codelog/2022-04-14-emacs-discontinue-mct/.
This manual, written by Protesilaos Stavrou, describes the customization
options for mct
(or mct.el
and variants), and provides every other piece
of information pertinent to it.
The documentation furnished herein corresponds to stable version {{{stable-version}}}, released on {{{release-date}}}. Any reference to a newer feature which does not yet form part of the latest tagged commit, is explicitly marked as such.
Current development target is {{{development-version}}}.
Copyright (C) 2021 Free Software Foundation, Inc.
Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.3 or any later version published by the Free Software Foundation; with no Invariant Sections, with the Front-Cover Texts being “A GNU Manual,” and with the Back-Cover Texts as in (a) below. A copy of the license is included in the section entitled “GNU Free Documentation License.”
(a) The FSF’s Back-Cover Text is: “You have the freedom to copy and modify this GNU manual.”
Minibuffer and Completions in Tandem, also known as “MCT”, “Mct”, mct
,
or mct.el
, is a package that enhances the default minibuffer and
*Completions*
buffer of Emacs 27 (or higher) so that they work together
as part of a unified framework. The idea is to make the presentation
and overall functionality be consistent with other popular, vertically
aligned completion UIs while leveraging built-in functionality.
The main feature set that unifies the minibuffer and the *Completions*
buffer consists of commands that cycle between the two, making it seem
like they are part of a contiguous space (Basic usage).
MCT tries to find a middle ground between the frugal defaults and the
more opinionated completion UIs. This is most evident in its approach
on how to present completion candidates. Instead of showing them
outright or only displaying them on demand, MCT implements a minimum
input threshold as well as a slight delay before it pops up the
*Completions*
buffer and starts updating it to respond to user input.
MCT is highly configurable to adapt to the varying needs of users. This section documents each user option.
Brief: Set the presentation of candidates in the Completions’ buffer.
Symbol: mct-completions-format
(choice
type)
Possible values:
one-column
(default—only works on Emacs 28 or higher)horizontal
vertical
By default, MCT tries to display completion candidates in a single
column. This only works for Emacs version 28 or higher. In older
versions of Emacs, the choices are between two grid views as explained
in the built-in user option completions-format
, with the fallback being
the horizontal
style.
Brief: Control auto-display and live-update of the *Completions*
buffer.
Symbol: mct-live-completion
(choice
type)
Possible values:
nil
t
(default)visible
This user option governs the overall behaviour of MCT with regard to how it uses the Completions’ buffer:
- When nil, the user has to manually request completions, using the regular activating commands (Usage). The Completions’ buffer is never updated live to match user input. Updating has to be handled manually. This is like the out-of-the-box minibuffer completion experience.
- When set to
visible
, the Completions’ buffer is live updated only if it is visible (present in a window). The actual display of the completions is still handled manually. For this reason, thevisible
style does not read themct-minimum-input
, meaning that it will always try to live update the visible completions, regardless of input length (Minimum input threshold). - When non-nil (the default), the Completions’ buffer is automatically
displayed once the
mct-minimum-input
is met and is hidden if the input drops below that threshold. While visible, the buffer is updated live to match the user’s input.
Note that every command or completion category that is declared in the
mct-completion-passlist
ignores this option altogether. This means that
every such symbol will always show the Completions’ buffer automatically
and will always update its contents live to match any further user input
(Passlist for commands or completion categories). Same principle for
the mct-completion-blocklist
, which will always disable both the
automatic display and live updating of the Completions’ buffer
(Blocklist for commands or completion categories).
Size boundaries of the Completions.
Brief: Try to live update completions when input is >= N.
Symbol: mct-minimum-input
(natnum
type)
By default, MCT expects the user to type 3
characters before it tries to
compute completion candidates, display the *Completions*
buffer and keep
it updated live to match any subsequent input.
Setting this user option to a value greater than 1 can help reduce the total number of candidates that are being computed. That is because the Completions can consist of thousands of items that all need to be rendered at once in a buffer.
In terms of the user experience, the minimum input threshold can make
sessions feel less visually demanding when the user (i) knows what they
are looking for and (ii) types fast enough so that the *Completions*
never have the time to pop up.
This variable is ignored for commands or completion categories that are
specified in the mct-completion-passlist
and mct-completion-blocklist
.
Live updates per command or completion category.
Brief: Delay in seconds before updating the Completions’ buffer.
Symbol: mct-live-update-delay
(number
type)
The delay in seconds between live updates of the Completions’ buffer.
The default value is 0.3
.
This variable is ignored for commands or completion categories that are
specified in the mct-completion-passlist
and mct-completion-blocklist
.
Live updates per command or completion category.
By default, MCT has the same behaviour across all types of completion.
Specifically, it respects the mct-live-completion
option on whether and
when to perform live completion, the mct-minimum-input
threshold before
doing so, and the mct-live-update-delay
between changes to the
*Completions*
buffer.
Live completion.
Minimum input threshold.
Delay between live updates.
A passlist and a blocklist can override those options for the commands or categories specified.
Brief: List of symbols where live completions are always enabled.
Symbol: mct-completion-passlist
(repeat symbol
type)
The value of this user option is a list of symbols. Those can refer to
commands like find-file
or completion categories such as file
, buffer
,
or what other packages define like Consult’s consult-location
category.
Any entry in the passlist ignores the value of mct-live-completion
and
the mct-minimum-input
. It also bypasses any possible delay introduced
by mct-live-update-delay
. In other words, it immediately displays the
*Completions*
buffer and instantly updates it to match user input.
Known completion categories.
Brief: List of symbols where live completions are always disabled.
Symbol: mct-completion-blocklist
(repeat symbol
type)
The value of this user option is a list of symbols. Those can refer to
commands like find-file
or completion categories such as file
, buffer
,
or what other packages define like Consult’s consult-location
category.
This means that they ignore mct-live-completion
. They do not
automatically display the Completions’ buffer, nor do they update it to
match user input.
The Completions’ buffer can still be accessed with commands that place
it in a window (such as mct-list-completions-toggle
,
mct-switch-to-completions-top
).
Perhaps a less drastic measure is to set mct-minimum-input
to an
appropriate value. Or better use mct-completion-passlist
.
Known completion categories.
Below are the known completion categories that can be added to the
mct-completion-passlist
and mct-completion-blocklist
(and relevant
custom code). This resource is non-exhaustive and will be updated to
match available information.
bookmark
buffer
charset
coding-system
color
command
(e.g.M-x
)customize-group
environment-variable
expression
face
file
function
(thedescribe-function
command bound toC-h f
)info-menu
imenu
input-method
kill-ring
library
minor-mode
multi-category
package
project-file
symbol
(thedescribe-symbol
command bound toC-h o
)theme
unicode-name
(theinsert-char
command bound toC-x 8 RET
)variable
(thedescribe-variable
command bound toC-h v
)
From the consult
package:
consult-grep
consult-isearch
consult-isearch
consult-kmacro
consult-location
From the embark
package:
embark-keybinding
In general, it is best not to add symbols which include several
thousands of candidates to the passlist. So no command
, function
,
symbol
, unicode-name
, variable
.
When in doubt, do not add a symbol to either the pass- or block- list.
Find completion category.
While using a command that provides a minibuffer prompt, type M-:
(the
eval-expression
command) and evaluate (mct--completion-category)
. It
will return the completion category, if any. Note that this only works
when the variable enable-recursive-minibuffers
is non-nil.
To review echo area messages, use C-h e
(view-echo-area-messages
).
Known completion categories.
Brief: Set the maximum and minimum height of the Completions’ buffer.
Symbol: mct-completion-window-size
(choice
type between nil and cons cell)
The value is a cons cell in the form of (max-height . min-height)
where
each value is either a natural number or a function which returns such a
number.
The default maximum height of the window is calculated by the function
mct--frame-height-fraction
, which finds the closest round number to
1/3 of the frame’s height. While the default minimum height is 1. This
means that during live completions the Completions’ window will shrink
or grow to show candidates within the specified boundaries. To disable
this bouncing effect, set both max-height and min-height to the same
number.
If nil, do not try to fit the Completions’ buffer to its window.
Live completion.
Brief: Whether to keep dynamic completion live.
Symbol: mct-persist-dynamic-completion
(boolean
type)
Possible values:
nil
t
(default)
Without any intervention from MCT, the default Emacs behavior for
commands such as find-file
or for a file
completion category is to hide
the *Completions*
buffer after updating the list of candidates in a
non-exiting fashion (e.g. select a directory and expect to continue
typing the path). This, however, runs contrary to the interaction model
of MCT when it performs live completions, because the user expects the
Completions’ buffer to remain visible while typing out the path to the
file (Live completion).
When this user option is non-nil (the default) it makes all non-exiting
commands keep the *Completions*
visible when updating the list of
candidates.
This applies to prompts in the file
completion category whenever the
user selects a candidate with mct-choose-completion-no-exit
,
mct-edit-completion
, minibuffer-complete
, minibuffer-force-complete
(i.e. any command that does not exit the minibuffer).
Selecting candidates with mct-minibuffer-mode.
The two exceptions are (i) when the current completion
session runs a command or category that is blocked by the
mct-completion-blocklist
or (ii) the user option mct-live-completion
is
nil.
Blocklist for commands or completion categories.
The underlying rationale:
Most completion commands present a flat list of candidates to choose
from. Picking a candidate concludes the session. Some prompts,
however, can recalculate the list of completions based on the selected
candidate. A case in point is find-file
(or any command with the file
completion category) which dynamically adjusts the completions to show
only the elements which extend the given file system path. We call such
cases “dynamic completion”. Due to their particular nature, these need
to be handled explicitly. The present user option is provided primarily
to raise awareness about this state of affairs.
Brief: Do not show a mode line in the Completions’ buffer.
Symbol: mct-hide-completion-mode-line
(boolean
type)
By default, the *Completions*
buffer has its own mode line, just like
every other window. Set this user option to non-nil to remove the mode
line.
Brief: Delete shadowed parts of file names from the minibuffer.
Symbol: mct-remove-shadowed-file-names
(boolean
type)
When the built-in file-name-shadow-mode
is enabled and this user option
is non-nil, MCT will delete the part of the file path that is shadowed
(meaning that it is overriden) by the given input.
For example, if the user types ~/
after a long path name, everything
preceding the ~/
is removed so the interactive selection process starts
again from the user’s $HOME
.
Brief: Use alternating backgrounds in the Completions.
Symbol: mct-apply-completion-stripes
(boolean
type)
By default, the *Completions*
buffer uses the main background of the
active theme (more specifically the :background
attribute of the default
face). When set to non-nil, MCT applies applies alternating background
colors in the Completions’ buffer. These are in a shade of gray that
contrasts with the main background.
Due to the specific nature of this style, there is no basic face that
can be inherited to achieve a consistent result across themes. As such,
it only looks as intended with the modus-themes
(built into Emacs 28 or
higher or available as a package). Other themes would need to add
support for the mct-stripe
face.
Emacs draws a distinction between two types of completion sessions:
- Completion where the minibuffer is involved (such as to switch buffers or find a file).
- Completion in a regular buffer to expand the text before point. The
minibuffer is not active. We call this “in-buffer completion” or
allude to the underlying function:
completion-in-region
.
The former scenario is what MCT has supported since its inception.
Starting with version 0.4.0
it also covers the latter case, though only
experimentally (please report any bugs or point towards areas of
possible improvement).
To let users fine-tune their setup, MCT provides the mct-minibuffer-mode
(formerly mct-mode
) as well as the global mct-region-mode
.
The decoupling between the two modes makes it possible to configure interchangeable components in a variety of combinations, such as MCT for the minibuffer and the Corfu package for completion-in-region (Extensions). Or the Vertico package for the minibuffer and MCT for in-buffer completion (Alternatives).
We jokingly say that since the introduction of mct-region-mode
the
acronym “MCT” now stands for “Minibuffer Confines Transcended”—the
original was “Minibuffer and Completions in Tandem”.
Interaction model of mct-region-mode.
This section outlines the various patterns of interaction that MCT
establishes. Note that completion covers two distinct cases, which are
reflected in the design of MCT: (i) in the minibuffer and (ii) for
in-buffer completion (MCT in the minibuffer and in regular buffers).
Most of this section is about the former scenario, which uses the
mct-minibuffer-mode
. The mct-region-mode
is less featureful by
comparison.
When mct-minibuffer-mode
is enabled, some new keymaps are activated
which add commands for cycling between the minibuffer and the
completions. Suppose the following standard layout:
----------------- | | | | Buffers| Buf | | | | ----------------- | | | | Buf | Buf | | | | ----------------- ----------------- | | | Completions | | | ----------------- ----------------- | Minibuffer | -----------------
When inside the minibuffer, pressing C-n
(or down arrow) takes you to
the top of the completions, while C-p
(or up arrow) moves to the bottom.
The commands are mct-switch-to-completions-top
for the former and
mct-switch-to-completions-bottom
for the latter. If the *Completions*
are not shown, then the buffer pops up automatically and point moves to
the given position.
Similarly, while inside the *Completions*
buffer, C-p
(or up arrow) at
the top of the buffer switches to the minibuffer, while C-n
(or down
arrow) at the bottom of the buffer also goes to the minibuffer. If
point is anywhere else inside the buffer, those key bindings perform a
regular line motion (if the *Completions*
are set to a grid view, then
the left and right arrow keys perform the corresponding lateral
motions). The commands are mct-previous-completion-or-mini
and
mct-next-completion-or-mini
. Both accept an optional numeric argument.
If the Nth line lies outside the boundaries of the completions’ buffer,
they move the point to the minibuffer.
The display of the *Completions*
can be toggled at any time from inside
the minibuffer with C-l
(mnemonic is “[l]ist completions” and the
command is mct-list-completions-toggle
).
By default, the *Completions*
buffer appears in a window at the bottom
of the frame. Users can change its placement by configuring the
variable mct-display-buffer-action
(its doc string explains how and
provides sample code).
This is not the same for in-buffer completion performed by
mct-region-mode
(Interaction model of mct-region-mode).
There are several ways to select a completion candidate. These pertain
to mct-minibuffer-mode
, as mct-region-mode
only has the meaningful
action of expanding the given candidate (with RET
or TAB
in the
Completions’ buffer (Cyclic behaviour for in-buffer completion)).
- Suppose that you are typing
mod
with the intent to select themodus-themes.el
buffer. To complete the candidate follow upmod
with theTAB
key (minibuffer-complete
). If the match is unique, the text will be expanded. Otherwise the*Completions*
buffer will appear. This does not exit the minibuffer, meaning that it does not confirm your choice. To confirm your choice, useRET
. If you ever make a mistake and expand the wrong candidate, just useundo
. Lastly note that if the candidates meet thecompletion-cycle-threshold
hittingTAB
again will switch between them. - While cycling through the completions’ buffer, type
RET
to select and confirm the current candidate (mct-choose-completion-exit
). This works for all types of completion prompts. - Similar to the above, but without exiting the minibuffer (i.e. to
confirm your choice) is
mct-choose-completion-no-exit
which is bound toTAB
in the completions’ buffer. This is particularly useful for certain contexts where selecting a candidate does not necessarily mean that the process has to be finalised (e.g. when usingfind-file
). In those cases, the event triggered byTAB
is followed by the renewal of the list of completions, where relevant (e.g.TAB
over a directory infind-file
, which then shows the contents of that directory).The command can correctly expand completion candidates even when the active style in
completion-styles
ispartial-completion
. In other words, if the minibuffer contains input like~/G/P/m
and the point is in the completions’ buffer overGit/Projects/mct/
the minibuffer’ contents will become~/Git/Projects/mct/
and then show the contents of that directory. - Type
M-e
(mct-edit-completion
) in the completions’ buffer to place the current candidate in the minibuffer, without exiting the session. This allows you to edit the text before confirming it. If point is in the minibuffer before performing this action, the current candidate is either the one at the top of the completions’ buffer or that which is under the last known point in said buffer (the last known position is reset when the window is deleted). Internally,mct-edit-completion
usesmct-choose-completion-no-exit
to expand the completion candidate, so it retains its behaviour (as explained right above).Sometimes there is a need to switch to the minibuffer without selecting the candidate at point, such as to retype some part of the input. In those cases, type
e
in the completions’ buffer to move to the minibuffer. The command is calledmct-focus-minibuffer
, which can also be assigned to the global keymap, though MCT leaves such a decision up to the user (same formct-focus-mini-or-completions
). - In prompts that allow the selection of multiple candidates
(internally via the
completing-read-multiple
function) usingM-RET
(mct-choose-completion-dwim
) in the*Completions*
will append the candidate at point to the list of selections and keep the completions available so that another item may be selected. Any of the aforementioned applicable methods can confirm the final selection. If, say, you want to pick a total of three candidates, doM-RET
for the first two andRET
(mct-choose-completion-exit
) for the last one. In contexts that are not CRM-powered, theM-RET
has the same effect asTAB
(mct-choose-completion-no-exit
).Indicator for completing-read-multiple.
- When point is at the minibuffer, select the current candidate in
the completions buffer with
C-RET
(mct-complete-and-exit
), which has the same effect as first completing withTAB
and then immediately exit the minibuffer with the completed candidate as the selected one. - Emacs 28 has the ability to group candidates inside the completions’
buffer under headings. For example, the Consult package makes use of
those (Third-party extensions). MCT provides motions that jump
between such headings, placing the point at the first candidate right
below the heading’s text. Use
M-n
(mct-next-completion-group
) andM-p
(mct-previous-completion-group
) to move to the next or previous one, respectively (also work with they keys forforward-paragraph
andbackward-paragraph
). Both commands accept an optional numeric argument. For the sake of avoiding surprises, these commands do not cycle between the completions and the minibuffer: they stop at the first or last heading.
When mct-region-mode
is enabled, MCT is used for in-buffer completion.
In this scenario, the cyclic behaviour is less featureful than when the
minibuffer is active (due to the specifics of the underlying commands),
so we cover the differences (Cyclic behaviour in the minibuffer).
In terms of its interaction model, mct-region-mode
only gets enabled
manually either by pressing TAB
or C-M-i
(complete-symbol
) in supporting
major modes. The *Completions*
buffer pops up and is narrowed live to
match any subsequent user input. While the buffer is visible, we are
performing completion-in-region
, which means that the Completions can be
narrowed live by typing further. Furthermore, C-n
or C-p
will move the
point to the top/bottom of the Completions’ buffer from where the user
can select a candidate with RET
.
In-buffer completion is always invoked manually. There is no minimum
input threshold and no delay between updates while live-updating of the
*Completions*
buffer is performed. If the Completions are not visible,
then no completion-in-region
takes place and thus mct-region-mode
should
have no effect.
By default, the placement of the Completions for this type of
interaction is below the current buffer (as opposed to the bottom of the
frame for mct-minibuffer-mode
). It looks like this:
------------------------ | | | | Current buffer| Buf | | | | ------------------------ | | | | Completions | Buf | | | | ------------------------ | | | | | Buf | Buf | Buf | | | | | ------------------------
While inside the Completions’ buffer, C-n
and C-p
move to the next and
previous line, respectively. When they reach the top/bottom boundaries
of the Completions’ buffer, they switch focus back to the buffer that
started the completion. However, and unlike mct-minibuffer-mode
, they
do not keep the *Completions*
window around. This is because we cannot
tell whether the user wanted to continue with a new completion upon
returning to the buffer of origin or perform some other motion/command
(in the minibuffer we can make that assumption because the minibuffer is
purpose-specific, so for as long as it is active, the completion session
goes on). As such, completion-in-region
must be restarted after cycling
out of the *Completions*
.
To cancel in-buffer completion, type C-g
either before switching to the
Completions’ buffer or while inside of it.
mct
is available on the official GNU ELPA archive for users of Emacs
version 27 or higher. One can install the package without any further
configuration. The following commands shall suffice:
M-x package-refresh-contents
M-x package-install RET mct
A package is also available via Guix:
guix package -i emacs-mct
Assuming your Emacs files are found in ~/.emacs.d/
, execute the
following commands in a shell prompt:
cd ~/.emacs.d
# Create a directory for manually-installed packages
mkdir manual-packages
# Go to the new directory
cd manual-packages
# Clone this repo and name it "mct"
git clone https://git.sr.ht/~protesilaos/mct mct
Finally, in your init.el
(or equivalent) evaluate this:
;; Make Elisp files in that directory available to the user.
(add-to-list 'load-path "~/.emacs.d/manual-packages/mct")
Everything is in place to set up the package.
Minimal setup for the minibuffer and in-buffer completion:
(require 'mct)
(mct-minibuffer-mode 1)
(mct-region-mode 1)
And with more options:
(require 'mct)
(setq mct-completion-window-size (cons #'mct--frame-height-fraction 1))
(setq mct-remove-shadowed-file-names t) ; works when `file-name-shadow-mode' is enabled
(setq mct-hide-completion-mode-line t)
(setq mct-apply-completion-stripes t)
(setq mct-minimum-input 3)
(setq mct-live-completion t)
(setq mct-live-update-delay 0.6)
(setq mct-persist-dynamic-completion t)
(setq mct-completions-format 'one-column)
;; This is for commands or completion categories that should always pop
;; up the completions' buffer. It circumvents the default method of
;; waiting for some user input (see `mct-minimum-input') before
;; displaying and updating the completions' buffer.
(setq mct-completion-passlist
'(;; Some commands
Info-goto-node
Info-index
Info-menu
vc-retrieve-tag
;; Some completion categories
imenu
file
buffer
kill-ring
consult-location))
;; The blocklist follows the same principle as the passlist, except it
;; disables live completions altogether.
(setq mct-completion-blocklist nil)
;; You can place the Completions' buffer wherever you want, by following
;; the syntax of `display-buffer'. For example, try this:
;; (setq mct-display-buffer-action
;; (quote ((display-buffer-reuse-window
;; display-buffer-in-side-window)
;; (side . left)
;; (slot . 99)
;; (window-width . 0.3))))
(mct-minibuffer-mode 1)
;; Optionally use MCT for in-buffer completion (though `corfu' is a
;; better option).
(mct-region-mode 1)
;;; Integration with Oleh Krehel's `avy' package
(require 'mct-avy)
(dolist (map (list mct-minibuffer-local-completion-map
mct-minibuffer-completion-list-map))
(define-key map (kbd "C-,") #'mct-avy-embark-act)
(define-key map (kbd "C-.") #'mct-avy-choose-completion-exit)
(define-key map (kbd "C-;") #'mct-avy-choose-completion-dwim))
;; If you are using `mct-region-mode':
(dolist (map (list mct-region-completion-list-map
mct-region-buffer-map))
(define-key map (kbd "C-,") #'mct-avy-embark-act)
(define-key map (kbd "C-.") #'mct-avy-region-choose-completion))
Other useful extras from the Emacs source code (read their doc strings):
(setq completion-styles
'(basic substring initials flex partial-completion))
(setq completion-category-overrides
'((file (styles . (basic partial-completion initials substring)))))
(setq completion-cycle-threshold 2)
(setq completion-ignore-case t)
(setq completion-show-inline-help nil)
(setq completions-detailed t)
(setq enable-recursive-minibuffers t)
(setq minibuffer-eldef-shorten-default t)
(setq read-buffer-completion-ignore-case t)
(setq read-file-name-completion-ignore-case t)
(setq resize-mini-windows t)
(setq minibuffer-eldef-shorten-default t)
(file-name-shadow-mode 1)
(minibuffer-depth-indicate-mode 1)
(minibuffer-electric-default-mode 1)
;; Do not allow the cursor in the minibuffer prompt
(setq minibuffer-prompt-properties
'(read-only t cursor-intangible t face minibuffer-prompt))
(add-hook 'minibuffer-setup-hook #'cursor-intangible-mode)
;;; Minibuffer history
(require 'savehist)
(setq savehist-file (locate-user-emacs-file "savehist"))
(setq history-length 10000)
(setq history-delete-duplicates t)
(setq savehist-save-minibuffer-history t)
(add-hook 'after-init-hook #'savehist-mode)
;;; Indentation and the TAB key
(setq-default tab-always-indent 'complete) ; useful for `mct-region-mode'
(setq-default tab-first-completion 'word-or-paren-or-punct) ; Emacs 27
;;; Third-party extensions
;;;; Enable Consult previews in the Completions buffer.
;; Requires the `consult' package.
(add-hook 'completion-list-mode-hook #'consult-preview-at-point-mode)
;;;; Setup for Orderless
;; Requires the `orderless' package
;; We make the SPC key insert a literal space and the same for the
;; question mark. Spaces are used to delimit orderless groups, while
;; the quedtion mark is a valid regexp character.
(let ((map minibuffer-local-completion-map))
(define-key map (kbd "SPC") nil)
(define-key map (kbd "?") nil))
;; Because SPC works for Orderless and is trivial to activate, I like to
;; put `orderless' at the end of my `completion-styles'. Like this:
(setq completion-styles
'(basic substring initials flex partial-completion orderless))
(setq completion-category-overrides
'((file (styles . (basic partial-completion orderless)))))
[ Part of {{{development-version}}} ]
The MCT code repository contains some Elisp files beside mct.el
which
extend the functionality of the core package. These files are named
like mct-SCOPE.el
. They are considered experimental for the time
being. Their target audience is developers or users who can tolerate
the occasional bug.
[ Part of {{{development-version}}} ]
The MCT repository contains the mct-avy.el
file. It integrates MCT
with the avy
package to choose completion candidates using the
latter’s mode of interaction. The commands it defines are:
mct-avy-choose-completion-exit
mct-avy-choose-completion-dwim
mct-avy-choose-completion-jump
mct-avy-region-choose-completion
mct-avy-embark-act
Their respective doc strings describe their functionality.
mct-avy.el
does not bind any keys. Choose your own with something
like this:
(dolist (map (list mct-minibuffer-local-completion-map
mct-minibuffer-completion-list-map))
(define-key map (kbd "C-;") #'mct-avy-choose-completion-exit)
(define-key map (kbd "C-,") #'mct-avy-embark-act)
(define-key map (kbd "M-;") #'mct-avy-choose-completion-dwim))
;; If you are using `mct-region-mode':
(dolist (map (list mct-region-completion-list-map
mct-region-buffer-map))
(define-key map (kbd "C-,") #'mct-avy-embark-act)
(define-key map (kbd "C-;") #'mct-avy-region-choose-completion))
mct-avy.el
is inspired by Omar Antolín Camarena’s
avy-embark-collect.el
. The mct-avy-choose
function borrows code
and/or ideas from that libary: https://github.com/oantolin/embark/.
Third-party extensions.
This section documents known issues and how to address them.
MCT uses its own overlay to highlight the candidate at point. To ensure
that it does not interfere with the optional stripes (provided by the
user option mct-apply-completion-stripes
) the highlight’s priority is
set to a custom value. This, in turn, means that when the user enables
global-hl-line-mode
, its highlighted line takes precedence over the MCT
highlight. The solution to this conflict is to disable the hl-line
locally for the *Completions*
buffer like this:
(add-hook 'completion-list-mode-hook (lambda () (setq-local global-hl-line-mode nil)))
MCT defines its own keymaps, which extend those that are active in the
minibuffer and the *Completions*
buffer, respectively:
mct-completion-list-mode-map
mct-minibuffer-local-completion-map
mct-region-buffer-map
mct-region-completion-list-map
You can invoke describe-keymap
to learn more about them.
If you want to edit any key bindings, do it in these keymaps, not in
those they extend and override (the names of the original ones are the
same as above, minus the mct-
prefix).
In this section we cover custom code that builds on what MCT offers.
Starting with Emacs 29 (current development target), the user option
completions-sort
controls the sorting method of candidates in the
*Completions*
buffer. Beside the default of using string-lessp
, it
accepts a custom function. Consider any of the following examples:
;; Some sorting functions...
(defun my-sort-by-alpha-length (elems)
"Sort ELEMS first alphabetically, then by length."
(sort elems (lambda (c1 c2)
(or (string-version-lessp c1 c2)
(< (length c1) (length c2))))))
(defun my-sort-by-history (elems)
"Sort ELEMS by minibuffer history.
Use `mct-sort-sort-by-alpha-length' if no history is available."
(if-let ((hist (and (not (eq minibuffer-history-variable t))
(symbol-value minibuffer-history-variable))))
(minibuffer--sort-by-position hist elems)
(my-sort-by-alpha-length elems)))
(defun my-sort-multi-category (elems)
"Sort ELEMS per completion category."
(pcase (mct--completion-category)
('nil elems) ; no sorting
('kill-ring elems)
('project-file (my-sort-by-alpha-length elems))
(_ (my-sort-by-history elems))))
;; Specify the sorting function.
(setq completions-sort #'my-sort-multi-category)
Known completion categories.
[ Part of {{{development-version}}} ]
Previous versions of MCT would prepend a [CRM]
tag to the minibuffer
prompt of commands powered by completing-read-multiple
. While this is a
nice usability enhancement, it is not specific to MCT and thus should
not be part of mct.el
. Use this in your init file instead:
;; Copied from Daniel Mendler's `vertico' library:
;; <https://github.com/minad/vertico>.
(defun my-crm-indicator (args)
"Add prompt indicator to `completing-read-multiple' filter ARGS."
(cons (concat "[CRM] " (car args)) (cdr args)))
(advice-add #'completing-read-multiple :filter-args #'my-crm-indicator)
[ Part of {{{development-version}}} ]
Older versions of MCT had a command for file navigation that would
delete the whole directory component before point, effectively going
back up one directory. While the functionality can be useful, it is not
integral to the MCT experience and thus should not belong in mct.el
.
Add this to your own configuration file instead:
;; Adaptation of `icomplete-fido-backward-updir'.
(defun my-backward-updir ()
"Delete char before point or go up a directory."
(interactive nil mct-minibuffer-mode)
(cond
((and (eq (char-before) ?/)
(eq (mct--completion-category) 'file))
(when (string-equal (minibuffer-contents) "~/")
(delete-minibuffer-contents)
(insert (expand-file-name "~/"))
(goto-char (line-end-position)))
(save-excursion
(goto-char (1- (point)))
(when (search-backward "/" (minibuffer-prompt-end) t)
(delete-region (1+ (point)) (point-max)))))
(t (call-interactively 'backward-delete-char))))
(define-key minibuffer-local-filename-completion-map (kbd "DEL") #'my-backward-updir)
Over at the rde project, Andrew Tropin configures MCT to display the Completions’ buffer in either of two places:
- Current window
- This is the default behaviour. It means that completions are presented where the user is already focused on, instead of the bottom of the display or some side window.
- Other window
- The least recently used window when the command that
performs completion matches certain categories whose candidates are
best shown next to the current window/context. For example, Imenu
(and extensions like
consult-imenu
) creates a dynamically generated index of “points of interest” in the current buffer, so it is useful to have this displayed in the other window.
Implementation details and particular preferences aside, this is a great
example of using the various display-buffer
functions to control the
placement of the *Completions*
buffer.
(defvar rde-completion-categories-other-window
'(imenu)
"Completion categories that has to be in other window than
current, otherwise preview functionallity will fail the party.")
(defvar rde-completion-categories-not-show-candidates-on-setup
'(command variable function)
"Completion categories that has to be in other window than
current, otherwise preview functionallity will fail the party.")
(defun rde-display-mct-buffer-pop-up-if-apropriate (buffer alist)
"Call `display-buffer-pop-up-window' if the completion category
one of `rde-completion-categories-other-window', it will make
sure that we don't use same window for completions, which should
be in separate window."
(if (memq (mct--completion-category)
rde-completion-categories-other-window)
(display-buffer-pop-up-window buffer alist)
nil))
(defun rde-display-mct-buffer-apropriate-window (buffer alist)
"Displays completion buffer in the same window, where completion
was initiated (most recent one), but in case, when compeltion
buffer should be displayed in other window use least recent one."
(let* ((window (if (memq (mct--completion-category)
rde-completion-categories-other-window)
(get-lru-window (selected-frame) nil nil)
(get-mru-window (selected-frame) nil nil))))
(window--display-buffer buffer window 'reuse alist)))
(setq mct-display-buffer-action
(quote ((display-buffer-reuse-window
rde-display-mct-buffer-pop-up-if-apropriate
rde-display-mct-buffer-apropriate-window))))
(defun rde-mct-show-completions ()
"Instantly shows completion candidates for categories listed in
`rde-completion-categories-show-candidates-on-setup'."
(unless (memq (mct--completion-category)
rde-completion-categories-not-show-candidates-on-setup)
(setq-local mct-minimum-input 0)
(mct--live-completions)))
(add-hook 'minibuffer-setup-hook 'rde-mct-show-completions)
MCT only tweaks the default minibuffer. To get more out of it, consider these exceptionally well-crafted extras:
- Consult by Daniel Mendler
- Adds several commands that make interacting with the minibuffer more powerful. There also are multiple packages that build on it, such as consult-dir by Karthik Chikmagalur and consult-notmuch by José Antonio Ortega Ruiz.
- Embark by Omar Antolín Camarena
- Provides configurable contextual actions for completions and many other constructs inside buffers. A genius package!
- Marginalia by Daniel and Omar
- Displays informative annotations for all known types of completion candidates.
- Orderless by Omar
- A completion style that matches a variety of patterns (regexp, flex, initialism, etc.) regardless of the order they appear in.
- all-the-icons-completion by Itai Y. Efrat
- Glue code that adds icons
from the
all-the-icons
package to the*Completions*
buffer. It can make things prettier and/or more informative, while it can also be combined with Marginalia.
MCT does support the use-case of completion-in-region
. This is the kind
of completion session that does not involve the minibuffer and is
instead about in-buffer text expansion. However, you may prefer:
- Corfu by Daniel Mendler
- An interface for the
completion-in-region
which uses a child frame (basically a pop-up) at the position of the cursor to display candidates. As with all of Daniel’s packages, Corfu aims for a clean implementation that does the right thing by being consistent with core Emacs mechanisms. - Cape also by Daniel
- Additional
completion-at-point-functions
(CAPFs) that extend those of core Emacs. These backends can be used by packages that visualisecompletion-in-region
such as Corfu and MCT.
One of the nice features of the Consult package is the ability to
preview the candidate at point. All we need to enable it in the
*Completions*
buffer is the following snippet:
(add-hook 'completion-list-mode-hook #'consult-preview-at-point-mode)
Daniel Mendler’s corfu
package provides an alternative to the
mct-region-mode
(MCT in the minibuffer and in regular buffers). Given
that MCT’s implementation is a global minor-mode, chances are that users
of both will run into weird issues with conflicting functionality. The
following snippet from Corfu’s README can be added to user configuration
files to avoid any potential trouble when using commands such as
eval-expression
(bound to M-:
by default):
(defun corfu-in-minibuffer ()
"Enable Corfu in the minibuffer only if Mct/Vertico are not active."
(unless (or (mct--minibuffer-p) vertico--input)
(corfu-mode 1)))
(add-hook 'minibuffer-setup-hook #'corfu-in-minibuffer 1)
In the grand scheme of things, it may be helpful to think of MCT as
proof-of-concept on how the default Emacs completion can become more
expressive. MCT’s value rests in its potential to inspire developers to
(i) patch Emacs so that its out-of-the-box completion is more
interactive, and (ii) expose the shortcomings in the current
implementation of the *Completions*
buffer, which should again provide
an impetus for further changes to Emacs. Otherwise, MCT is meant for
users who can tolerate the status quo and simply want a thin layer of
interactivity for minibuffer completion, in-buffer completion, and their
intersection with the Completions’ buffer.
Like MCT, these alternatives provide a thin layer of functionality over
the built-in infrastructure. Unlike MCT, they are not constrained by
the design of the *Completions*
buffer and concomitant functionality.
They all make for a natural complement to the standard Emacs experience
(also Extensions).
- Vertico by Daniel Mendler
- this is a more mature and feature-rich
package with a large user base and a highly competent maintainer.
Vertico has some performance optimizations on how candidates are sorted and presented, which means that it displays results right away without any noticeable performance penalty. Whereas MCT does not change the underlying behaviour of how candidates are displayed. As such, MCT will be slower in scenaria where there are lots of candidates because core Emacs lacks those optimizations. One such case is with the
describe-symbol
(C-h o
) prompt. If the user asks for the completions’ buffer without inputting any character (so without narrowing the list), there will be a noticeable delay before the buffer is rendered. This is mitigated in MCT by the requirement formct-minimum-input
, though the underlying mechanics remain intact.In terms of the interaction model, the main difference between Vertico and MCT is that the former uses the minibuffer by default and shows the completions there. The minibuffer is expanded to show the candidates in a vertical list. Whereas MCT keeps the
*Completions*
buffer and the minibuffer as separate entities, the way standard Emacs does it.The presence of a fully fledged buffer means that the user can invoke all relevant commands at their disposal, such as to write the buffer to a file for future review, use Isearch to move around, copy a string or rectangle to a register, and so on. Also, the placement of such a buffer is configurable (as with all buffers—though refer, in particular, to
mct-display-buffer-action
).Vertico has official extensions which can make it work exactly like MCT without any of MCT’s drawbacks. These extensions can also expand Vertico’s powers such as by providing granular control over the exact style of presentation for any given completion category (e.g. display Imenu in a separate buffer, show the
switch-to-buffer
list horizontally in the minibuffer, and presentfind-file
in a vertical list—whatever the user wants).All things considered, there is no compelling reason why one may prefer MCT over Vertico in terms of the available functionality: Vertico is better.
- Elmo - Embark Live MOde for Emacs by Karthik Chikmagalur
- this
package is best described as a sibling of MCT both in terms of its
functionality and overall interaction model. In fact, the cyclic
motions that are at the core of the MCT experience were first
developed as part of my personal Emacs setup to cycle between the
minibuffer and Embark’s “live completions” buffer. That was until
Emacs28 got some refinements to the presentation of the
*Completions*
buffer which allowed for a vertical, single-column view.Elmo can, in principle, have identical functionality with MCT, given that the only substantive difference is that the former uses an Embark buffer to show live-updating completions, while the latter relies on the generic
*Completions*
buffer.For users who are on Emacs 27 and who need a single-column view, Elmo is a better choice because MCT can only display such a view on Emacs 28 or higher (though it has been meticulously tested with the grid views of Emacs 27 and should work perfectly fine with them).
- Icomplete and fido-mode (built-in, multiple authors)
- Icomplete is
closer in spirit to Vertico, as it too uses the minibuffer to display
completion candidates. By default, it presents the list horizontally,
though there exists
icomplete-vertical-mode
(andfido-vertical-mode
).For our purposes, Icomplete and Fido are the same in terms of the paradigm they follow. The latter is a re-spin of the former, as it adjusts certain variables and binds some commands for the convenience of the end-user.
fido-mode
and its accoutrements are defined inicomplete.el
.What MCT borrows from Icomplete is for the input delay (explained elsewhere in this document). Internally, I also learnt how to extend local keymaps by studying
icomplete.el
.I had used Icomplete for several months before moving to what now has become
mct.el
. I think it is excellent at providing a thin layer over the built-in infrastructure.
MCT is meant to be a collective effort. Every bit of help matters.
- Author/maintainer
- Protesilaos Stavrou.
- Contributions to code or documentation
- Daniel Mendler, James Norman Vladimir Cash, José Antonio Ortega Ruiz, Juri Linkov, Philip Kaludercic, Tomasz Hołubowicz.
- Ideas and user feedback
- Andrew Tropin, Benjamin (@zealotrush), Case Duckworth, Chris Burroughs, Jonathan Irving, José Antonio Ortega Ruiz, Kostadin Ninev, Manuel Uberti, Morgan Willcock, Philip Kaludercic, Theodor Thornhill, Tomasz Hołubowicz, Z.Du. As well as users: danrobi11.
- Packaging
- Andrew Tropin and Nicolas Goaziou (Guix).
- Inspiration for certain features
icomplete.el
(built-in—multiple authors), Daniel Mendler (vertico
), Omar Antolín Camarena (embark
,live-completions
), Štěpán Němec (stripes.el
).
- Manual
- https://protesilaos.com/emacs/mct
- Change log
- https://protesilaos.com/emacs/mct-changelog
- Source code
- https://git.sr.ht/~protesilaos/mct
- Mailing list
- https://lists.sr.ht/~protesilaos/mct