jimbonator / tads-cookbook Goto Github PK

Problem

The TADS 3 menu system on native interpreters (both text only and HTML TADS variants) are not accessible for players using screen readers.
This is due to the way the banner API works, and how they're usually displayed by interpreters.

Solution

Create an InitObject that asks the player if they're using a screen reader, and adjust the statusLine.statusDispMode to StatusModeText if so.
The reason we need to change the statusLine.statusDispMode variable is because the menu system displays menus in whichevermode the status line is displayed in.

screenReaderInit: InitObject
execute()
{
"\bAre you using a screen reader to play this story? (Yes or no.)";
if(yesOrNo())
{
statusLine.statusDispMode = StatusModeText;
}
}
;

You can use the exact same code for both adv3 and adv3lite, so there's no need to change the code depending on what library you use.

Problem

It can useful to tell new or returning players what the background for the game is: where the game is set or who the player character is. While this might be obvious from an EXAMINE ME, you might want to elaborate some more.

It'd be nice to have some initial hints to guide them in the right direction.

Solution

Add a few game hints with permanently open goals so the hints on the backstory are always available:

TopHintMenu 'Hints';

+ HintMenu 'The Basics';

++ Goal 'Where am I?'
    ['You are in the TADS Cookbook kitchen.']
    openWhen = true
;

++ Goal 'Who am I?'
    ['You are the AFGNCAAP: the ageless, faceless, gender-neutral, culturally-ambiguous adventure person.']
    openWhen = true
;

To get to this menu, a player needs to type HINT (and then again after the warning). To disable the warning, you can do so at game initialization:

InitObject
    execute() {
        sessionHintStatus.hintWarning = true;
        gameHintStatus.hintWarning = true;
    }

To remap HELP to HINT:

DefineIAction(Help)
    execAction() {
        if (gHintManager != nil)
            gHintManager.showHints();
        else
            mainReport(gLibMessages.hintsNotPresent);
    }
;

VerbRule(Help)
    'help'
    : HelpAction
    verbPhrase = 'show/showing help'
;

Problem Statement

When using tokens in strings to automatically conjugate verbs, there is a case where a verb will "reset" the context of the sentence, causing following verbs to conjugate according to a default "it" noun.

The following demonstrates this behavior:

"{I} {hold} onto the ledge, drop{s/?ed},
and land{s/ed} on the floor below.";

creates:

I hold onto the ledge, drops, and lands on the floor below.

Solution

To fix this, the following code provides a new conjugation token (written as {aac}). Simply add or include this code before the rest of your project to make use of it:

/*
 * Actor Action Continuer (AAC)
 * Joseph Cramsey
 */
actorActionContinuer_: dummy_ {
    person = (gActor == nil ? 3 : gActor.person)
    plural = (gActor == nil ? nil : gActor.plural)
}

// A modified englishMessageParams will have our new token.
modify englishMessageParams {
    construct() {
        // Add the simplified message token
        params = params.append(['aac', { ctx, params:
            cmdInfo(ctx, actorActionContinuer_, &dummyName, vSubject)
        }]);

        inherited();
    }
}

With this, we now have the following behavior for all strings:

"{I} {hold} onto the ledge,{aac} drop{s/?ed},{aac}
and land{s/ed} on the floor below.";

creates:

I hold onto the ledge, drop, and land on the floor below.

As long as the {aac} token precedes a verb, the verb will be conjugated according to the gActor of the current action.