# Note: This should be the same bucket that is used by the transformer to produce data to load
module "s3_pipeline_bucket" {
  source = "snowplow-devops/s3-bucket/aws"

  bucket_name = "your-bucket-name"
}

# Note: This should be the same queue that is passed to the transformer to produce data to load
resource "aws_sqs_queue" "sf_message_queue" {
  content_based_deduplication = true
  kms_master_key_id           = "alias/aws/sqs"
  name                        = "sf-loader.fifo"
  fifo_queue                  = true
}

module "transformer_wrj" {
  source  = "snowplow-devops/transformer-kinesis-ec2/aws"

  name       = "transformer-server-wrj"
  vpc_id     = var.vpc_id
  subnet_ids = var.subnet_ids

  stream_name             = module.enriched_stream.name
  s3_bucket_name          = module.s3_pipeline_bucket.id
  s3_bucket_object_prefix = "transformed/good/widerow/json"
  window_period_min       = 1
  sqs_queue_name          = aws_sqs_queue.sf_message_queue.name

  transformation_type = "widerow"
  widerow_file_format = "json"

  ssh_key_name     = "your-key-name"
  ssh_ip_allowlist = ["0.0.0.0/0"]

  # Linking in the custom Iglu Server here
  custom_iglu_resolvers = [
    {
      name            = "Iglu Server"
      priority        = 0
      uri             = "http://your-iglu-server-endpoint/api"
      api_key         = var.iglu_super_api_key
      vendor_prefixes = []
    }
  ]
}

module "sf_loader" {
  source = "snowplow-devops/snowflake-loader-ec2/aws"

  name       = "sf-loader-server"
  vpc_id     = var.vpc_id
  subnet_ids = var.subnet_ids

  sqs_queue_name = aws_sqs_queue.sf_message_queue.name

  snowflake_loader_user        = "<USER>"
  snowflake_password           = "<PASSWORD>"
  snowflake_warehouse          = "<WAREHOUSE>"
  snowflake_database           = "<DATABASE>"
  snowflake_schema             = "<SCHEMA>"
  snowflake_region             = "<REGION>"
  snowflake_account            = "<ACCOUNT>"
  snowflake_aws_s3_bucket_name = module.s3_pipeline_bucket.id

  ssh_key_name     = "your-key-name"
  ssh_ip_allowlist = ["0.0.0.0/0"]

  # Linking in the custom Iglu Server here
  custom_iglu_resolvers = [
    {
      name            = "Iglu Server"
      priority        = 0
      uri             = "http://your-iglu-server-endpoint/api"
      api_key         = var.iglu_super_api_key
      vendor_prefixes = []
    }
  ]
}