Embedded server: starting with the operating system about brookframework HOT 3 CLOSED

(*
  Brook FCL HTTP Daemon Broker unit.

  Copyright (C) 2013 Silvio Clecio.

  http://brookframework.org

  All contributors:
  Plase see the file CONTRIBUTORS.txt, included in this
  distribution.

  See the file LICENSE.txt, included in this distribution,
  for details about the copyright.

  This library is distributed in the hope that it will be useful,
  but WITHOUT ANY WARRANTY; without even the implied warranty of
  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
*)

unit BrookFCLHTTPDaemonBroker;

{$mode objfpc}{$H+}

interface

uses
{$IFDEF MSWINDOWS}
  ServiceManager,
{$ENDIF}
  BrookFCLHTTPAppBroker, BrookApplication, BrookConsts, DaemonApp, Classes,
  SysUtils;

type

  { TBrookDaemonApplication }

  TBrookDaemonApplication = class(TInterfacedObject, IBrookApplication)
  public
    constructor Create;
    function Instance: TObject;
    procedure Run;
  end;

  { TBrookDaemonThread }

  TBrookDaemonThread = class(TThread)
  public
    procedure Execute; override;
  end;

  { TBrookHTTPDaemon }

  TBrookHTTPDaemon = class(TCustomDaemon)
  private
    FThread: TThread;
  public
    function Install: Boolean; override;
    function Uninstall: Boolean; override;
    function Start: Boolean; override;
    function Stop: Boolean; override;
    procedure Log(const AMsg: string);
  end;

  { TBrookHTTPDaemonMapper }

  TBrookHTTPDaemonMapper = class(TCustomDaemonMapper)
  public
    constructor Create(AOwner: TComponent); override;
  end;

implementation

var
  _BrookHTTPApp: IBrookApplication = nil;

function BrookHTTPApp: IBrookApplication;
begin
  if not Assigned(_BrookHTTPApp) then
    _BrookHTTPApp := TBrookApplication.Create;
  Result := _BrookHTTPApp;
end;

{ TBrookDaemonApplication }

constructor TBrookDaemonApplication.Create;
begin
  Application.Title := 'Brook HTTP daemon application';
end;

function TBrookDaemonApplication.Instance: TObject;
begin
  Result := BrookHTTPApp.Instance;
end;

procedure TBrookDaemonApplication.Run;
begin
  Application.Run;
end;

{ TBrookDaemonThread }

procedure TBrookDaemonThread.Execute;
begin
  BrookHTTPApp.Run;
end;

{ TBrookHTTPDaemon }

function TBrookHTTPDaemon.Start: Boolean;
begin
  Result := inherited Start;
  FThread := TBrookDaemonThread.Create(True);
  FThread.Start;
  Log('Start.');
end;

function TBrookHTTPDaemon.Stop: Boolean;
begin
  Result := inherited Stop;
  FThread.Terminate;
  Log('Stop.');
end;

function TBrookHTTPDaemon.Install: Boolean;
{$IFDEF MSWINDOWS}
var
  VSM: TServiceManager;
{$ENDIF}
begin
  Result := inherited Install;
{$IFDEF MSWINDOWS}
  VSM := TServiceManager.Create(nil);
  try
    VSM.Connect;
    if VSM.Connected then
      VSM.StartService(BROOK_HTTP_DAEMON_NAME, nil);
    VSM.Disconnect;
  finally
    VSM.Free;
  end;
{$ENDIF}
  Log('Install.');
end;

function TBrookHTTPDaemon.Uninstall: Boolean;
{$IFDEF MSWINDOWS}
var
  VSM: TServiceManager;
{$ENDIF}
begin
  Result := inherited Uninstall;
{$IFDEF MSWINDOWS}
  VSM := TServiceManager.Create(nil);
  try
    VSM.Connect;
    if VSM.Connected then
      VSM.StopService(BROOK_HTTP_DAEMON_NAME, True);
    VSM.Disconnect;
  finally
    VSM.Free;
  end;
{$ENDIF}
  Log('Uninstall.');
end;

procedure TBrookHTTPDaemon.Log(const AMsg: string);
begin
  Application.Log(etCustom, ClassName + ': ' + AMsg);
end;

{ TBrookHTTPDaemonMapper }

constructor TBrookHTTPDaemonMapper.Create(AOwner: TComponent);
var
  VDaemonDef: TDaemonDef;
begin
  inherited Create(AOwner);
  VDaemonDef := DaemonDefs.Add as TDaemonDef;
  VDaemonDef.Description := 'Brook HTTP daemon.';
  VDaemonDef.DisplayName := 'Brook daemon';
  VDaemonDef.Name := BROOK_HTTP_DAEMON_NAME;
  VDaemonDef.DaemonClassName := 'TBrookHTTPDaemon';
  VDaemonDef.WinBindings.ServiceType := stWin32;
end;

initialization
  RegisterDaemonClass(TBrookHTTPDaemon);
  RegisterDaemonMapper(TBrookHTTPDaemonMapper);
  BrookUnregisterApp;
  BrookRegisterApp(TBrookDaemonApplication.Create);

end.