AbstractMethodError When Using Kotlin Extension Functions (reified, inline, and crossinline keywords) with Java Swing Components that Use ActionEvent about proguard HOT 4 CLOSED

       // This will include the Kotlin library jars, it will be needed even though Shadow JAR already includes it
        // to solve all warnings that are related to Kotlin without ignoring them
        injars(sourceSets.main.get().compileClasspath)

tasks.register<proguard.gradle.ProGuardTask>("proguard") {
    dependsOn(tasks.shadowJar)
    configuration("proguard.pro")

    injars(tasks.shadowJar.flatMap { it.archiveFile })
    outjars(project.layout.buildDirectory.file("proguard-obfuscated.jar"))

    val javaHome = System.getProperty("java.home")
    // Automatically handle the Java version of this build.
    if (System.getProperty("java.version").startsWith("1.")) {
        // Before Java 9, the runtime classes were packaged in a single jar file.
        libraryjars("$javaHome/lib/rt.jar")
    } else {
        // As of Java 9, the runtime classes are packaged in modular jmod files.
        libraryjars(
            // filters must be specified first, as a map
            mapOf("jarfilter" to "!**.jar", "filter" to "!module-info.class"),
            "$javaHome/jmods/java.base.jmod"
        )
        // Needed to support Java Swing/Desktop
        libraryjars(
            mapOf("jarfilter" to "!**.jar", "filter" to "!module-info.class"),
            "$javaHome/jmods/java.desktop.jmod",
        )
    }

    allowaccessmodification()
    dontobfuscate()
    dontoptimize()
    verbose()

    // This will include the Kotlin library jars, Shadow JAR already includes it
    libraryjars(sourceSets.main.get().compileClasspath)

    printmapping(project.layout.buildDirectory.file("proguard-mapping.txt"))
}